N-OSM-Overpass-API

• Datenabfragen in OSM Datenbank auf http://overpass-turbo.eu/

Manual

• http://overpass-turbo.eu/
• https://wiki.openstreetmap.org/wiki/Overpass_API/Overpass_QL
• https://wiki.openstreetmap.org/wiki/Overpass_API/Overpass_API_by_Example

Beispiele

Globale EInstellungen

// This is a typical settings declaration line
// json output format
//out:{json|xml|csv} (json: not to be confused with geoJSON) 
//[out:csv( fieldname_1 [,fieldname_n ...] [; csv-headerline [; csv-separator-character ] ] )]
// A bbox framing the German city of Bonn [bbox:50.6,7.0,50.8,7.3]
[out:json][timeout:25][maxsize:1073741824][bbox:50.6,7.0,50.8,7.3];
...

Was hat Axel hier gemacht

[out:json];
node(user:hoxel)({{bbox}});
out meta;

finde das node mit ixi tag in Indien

[out:json];
node(user:hoxel)["ixi"]({{bbox}});
out meta;

=Coloring Style

[out:json];

(
  node(user:hoxel)({{bbox}});
  way(user:hoxel)({{bbox}});
  relation(user:hoxel)({{bbox}});
);
out body;
>;
out skel qt;

{{style: /* this is the MapCSS stylesheet */
node, area
{ color:gray; fill-color:gray; }

node[amenity=drinking_water],
node[amenity=fountain]
{ color:blue; fill-color:blue; }

node[amenity=place_of_worship],
area[amenity=place_of_worship]
{ color:grey; fill-color:grey; }

node[amenity=~/(restaurant|hotel|cafe)/],
area[amenity=~/(restaurant|hotel|cafe)/]
{ color:red; fill-color:red; }

node[amenity=parking],
area[amenity=parking]
{ color:yellow; fill-color:yellow; }

node[amenity=bench]
{ color:brown; fill-color:brown; }

node[amenity=~/(kindergarten|school|university)/],
area[amenity=~/(kindergarten|school|university)/]
{ color:green; fill-color:green; }
}}

Hausnummer im "node" oder im "way" definieren

http://overpass-turbo.eu/s/PRM

/*
Wie taged man die Hausnummer:
Manchmal an Nodes (rot) und manchmal an Ways (green)
*/
[out:json];
(
  node["addr:housenumber"]({{bbox}}); 
  way["addr:housenumber"]({{bbox}});
  ._ >; 
);
out meta;

{{style: /* this is the MapCSS stylesheet */
node
{ color:grey; fill-color:grey; }

node[addr:housenumber]
{ color:red; fill-color:red; }

way[addr:housenumber]
{ color:green; fill-color:green; }
}}

Shops

http://overpass-turbo.eu/s/PRV

/*
MOBIL UND BÄCKER shops*/
[out:json];
(
  node["shop"="mobile_phone"]({{bbox}}); 
  node["shop"="bakery"]({{bbox}}); 
  way["shop"="mobile_phone"]({{bbox}});
  ._ >; 
  way["shop"="bakery"]({{bbox}});
  ._ >; 
);
out meta;

{{style: /* this is the MapCSS stylesheet */
node
{ color:grey; fill-color:grey; }

node[shop=bakery],
way[shop=bakery]
{ color:red; fill-color:red; }

node[shop=mobile_phone],
way[shop=mobile_phone]
{ color:green; fill-color:green; }
}}

Junge Bäcker

http://overpass-turbo.eu/s/PRX

/*
Junge Bäcker shops*/
[out:json];
(
  node["name"~"Junge"]["shop"="bakery"]({{bbox}}); 
  way["name"~"Junge"]["shop"="bakery"]({{bbox}});
  ._ >; 
);
out;

{{style: /* this is the MapCSS stylesheet */
node
{ color:grey; fill-color:grey; }

node[shop=bakery]
{ color:red; fill-color:red; }

way[shop=bakery]
{ color:green; fill-color:green; }
}}

Was hat Hoxel hier so gemacht

http://overpass-turbo.eu/s/PSR

/* Welche nodes/ways hat hoxel ALS LETZTES bearbeitet. */
[out:json];
(node(user:hoxel)({{bbox}});way(user:hoxel)({{bbox}});._ >; );
out meta;

Wieviele Junge Filialen sind eingezeichnet

[out:json];
(
  node["name"~"Junge"]["shop"="bakery"]({{bbox}}); 
  way["name"~"Junge"]["shop"="bakery"]({{bbox}});
);
out count;

Ergibt:

...  "tags": {"nodes": "126","ways": "12","relations": "0","total": "138"} ...

Die Junge Seite ergibt:197Filialen

source=solar in HL

http://overpass-turbo.eu/s/PSX

[out:json];
(
  node["plant:source"=solar]({{bbox}}); 
  way["plant:source"=solar]({{bbox}});
  ._ >; 
  node["generator:source"=solar]({{bbox}}); 
  way["generator:source"=solar]({{bbox}});
  ._ >; 
);
out;

{{style: /* this is the MapCSS stylesheet */
node
{ color:grey; fill-color:grey; }

node[generator:source=solar][plant:source=solar],way[generator:source=solar][plant:source=solar]
{ color:orange; fill-color:orange; }

node[generator:source=solar],way[generator:source=solar]
{ color:blue; fill-color:blue; }

node[plant:source=solar],way[plant:source=solar]
{ color:green; fill-color:green; }
}}

Lübecker Stolpersteine

http://overpass-turbo.eu/s/PSU

[out:json];
(
node["memorial:type"=stolperstein]({{bbox}}); 
node[network="Stolpersteine Lübeck"]({{bbox}}); 
);
out meta;
{{style: /* this is the MapCSS stylesheet */
node
{ color:red; fill-color:red; }

node[memorial:type=stolperstein][network=Stolpersteine Lübeck][historic=memorial]
{ color:green; fill-color:green; }
}}

energiererzeuger

http://overpass-turbo.eu/s/PYD

/* Energie Generation Overview */
[out:json];
(
  node[power=generator]({{bbox}}); 
  way[power=generator]({{bbox}});
  ._ >; 
);
out meta;

{{style: /* this is the MapCSS stylesheet */
node,way
{ color:red; fill-color:red; }

node[generator:source=solar],node[plant:source=solar],way[generator:source=solar],way[plant:source=solar]
{ color:yellow; fill-color:yellow; }

node[generator:source=hydro],way[generator:source=hydro]
{ color:blue; fill-color:blue; }

node[generator:source=wind],node[plant:source=wind],way[generator:source=wind],way[plant:source=wind]
{ color:grey; fill-color:grey; }


node[generator:source=biogas],node[plant:source=biogas],way[generator:source=biogas],way[plant:source=biogas],node[generator:source=biomass],node[plant:source=biomass],way[generator:source=biomass],way[plant:source=biomass]
{ color:green; fill-color:green; }

http://overpass-turbo.eu/s/Q7C

[out:json];
area[name="Lübeck"][admin_level=6][boundary=administrative];
(
  node[power=generator](area); 
  way[power=generator](area);
  ._ >; 
);
out meta;
...

csv

• http://overpass-turbo.eu/s/Q7v
• https://wiki.openstreetmap.org/wiki/Overpass_API/Overpass_QL#CSV_header_line

[out:csv(::id,"generator:source","generator:method","generator:output:electricity","generator:output:heat";true;",")][timeout:25];
node["power"="generator"]({{bbox}});
out;